import com.android.build.api.dsl.ApplicationExtension
import com.android.build.api.dsl.LibraryExtension

plugins {
    alias(libs.plugins.hilt) apply false
    alias(libs.plugins.kotlin.kapt) apply false

    alias(libs.plugins.kotlin.android) apply false
    alias(libs.plugins.android.application) apply false
    alias(libs.plugins.android.library) apply false
}

subprojects {
    plugins.withId("com.android.application") {
        extensions.configure<ApplicationExtension> {
            composeOptions {
                kotlinCompilerExtensionVersion = libs.versions.kotlinCompilerExtension.get()
            }
        }
    }

    plugins.withId("com.android.library") {
        extensions.configure<LibraryExtension> {
            composeOptions {
                kotlinCompilerExtensionVersion = libs.versions.kotlinCompilerExtension.get()
            }
        }
    }
}
